Lately a lot of people seem to be having some troubles in determining the appropriate subnet mask to use in site boundaries to assign clients when using IP subnet type boundaries (SMS site boundaries and roaming boundaries and Configuration Manager boundaries). When defining boundaries by IP subnets, you can't use superneted addresses--only standard subnet addresses like you would find in DHCP scopes can be used. To get around adding in a ton of IP subnets, you can just ensure that the required IP subnets have been configured for an AD site and use that as the boundary. When using IP subnets as a boundary, the subnets entered must be what clients resolve their subnet mask to be.
To determine the IP subnet that a client believes it lives in (and so what IP subnet to define as a boundary), you have to convert the IP address and subnet mask to binary numbers, keep the bits in the IP address that have bits set in the subnet mask, and then convert the result back to decimal. For example:
A client with a 10.10.67.66 IP address with a subnet mask of 255.255.255.0 would be in the 10.10.67.0 IP subnet...easy enough. Now, change the subnet mask to 255.255.255.192 and what subnet do you have now? <long pause as I get out my binary calculator and do some conversions and give myself a slight headache> Viola! 10.10.67.64. Easy enough right? Well, this is why there is a plethora of subnetting calculators out there I suppose. I just find it easier to run this script on a client computer 
Subnetting and I have never really made friends so I love this script. It's an oldie first published in the SMS 2003 Concepts, Planning, and Deployment Guide and I make sure that I always keep this script handy when setting up my lab environments.
For best results, run this from the command prompt using the CSCRIPT option: CSCRIPT subnet.vbs. Get the script HERE (right click and select Save Target As... then change the extension from .txt to .vbs when you're ready to use it).
Here's the script (.vbs):
'subnet.vbs - displays the subnet for the computer's (or given) IP
' addresses and subnet masks
Set Arguments = Wscript.Arguments
If Wscript.Arguments.Count=2 Then
SubNetIT Arguments(0), Arguments(1)
Wscript.Echo ""
Else
Set loc = CreateObject( "WbemScripting.SWbemLocator" )
Set WbemServices = loc.ConnectServer( ,"root\cimv2" )
Set Adapters=WbemServices.ExecQuery( "Select * FROM" & _
" Win32_NetworkAdapterConfiguration" )
For Each Adapter in Adapters
If NOT IsNull( Adapter.IPAddress) Then
WScript.Echo "Description: ", Adapter.Description
SubNetIt Adapter.IPAddress(0), Adapter.IPSubnet(0)
WScript.Echo ""
End If
Next
WScript.Echo "You can also specify an address and subnet mask as " & _
"parameters to this script."
WScript.Echo ""
End If
WScript.Echo "At least one subnet must be a site's boundary for this computer"
WScript.Echo "to be assigned as a client."
Sub SubNetIt( Address, Subnet )
WScript.Echo "IP address: ", Address
WScript.Echo "subnet mask: ", Subnet
dim addressbytes(4)
dim subnetmaskbytes(4)
i=0
period = 1
while period<>len( address ) + 2
prevperiod=period
period = instr( period+1, address, "." ) + 1
if period = 1 then period = len( address ) + 2
addressbyte = mid( address, prevperiod, period-prevperiod-1 )
addressbytes(i)=addressbyte
i=i+1
wend
i=0
period = 1
while period<>len( subnet ) + 2
prevperiod=period
period = instr( period+1, subnet, "." ) + 1
if period = 1 then period = len( subnet ) + 2
subnetmaskbyte = mid( subnet, prevperiod, period-prevperiod-1)
subnetmaskbytes(i)=subnetmaskbyte
i=i+1
wend
subnet=""
for i=0 to 3
subnet = subnet & (addressbytes(i) AND subnetmaskbytes(i)) & "."
next
subnet = left( subnet, len(subnet)-1 )
WScript.Echo "subnet: ", subnet
End Sub
Hope it helps,
~Jeff